Enhancement Shaman Macros

There is probably not a day where I don’t get a whisper or an email about macros. The big advavntage of using macros is that they increase your focus on the game by covering easy tasks and they let you save those precious slots on action bars. The more and tighter macros you are using the more flexibility you are losing, too. It is your choice how far you want to go.

Personal Preferance

Basically I like to have my attacks semi automated so that I don’t have to pay too much attention for silly cooldowns and instead have more focus to dodge those pesky traps, fires and void zones. The remaining macros are used to to simply save space on action bars.

Minify Macros

Enhancement shaman macros can get complex quite fast, hence we need to keep them as short as possible. Basically all my macros are minified alread, but as general rule of thumb you can use for example:

  • mod instead of modifier
  • btn instead of button
  • itemid instead of name
  • /use instead of /cast
  • @ instead of target=
  • worn instead of equipped

Note: Basically select the red „?“ as icon for all macros, then they will always display the next ability.

Note: The script to find your item id’s is at the bottom.

Stormstrike Macro

#showtooltip
/cast [worn:Fishing Poles] Fishing
/stopmacro [worn:Fishing Poles,nocombat]
/cast Stormstrike
/use 14
/startattack
/stopmacro [worn:One-Hand]
/equipslot 16 item:71782:4099
/equipslot 17 item:71312:4099

  • Stormstrike + Trinket, Fishing with pole equipped, should you get into combat and not use weapons it will equip  them
  • Line 1: show the proper tooltip for the active ability
  • Line 2: if you are having a fishing pole equipped, cast fishing!
  • Line 3: if you have a fishing pole equipped and are not in combat stop here – if you are in combat it will equip your melee weaposn later
  • Line 4: cast Stormstrike
  • Line 5: use trinket, wanted that here instead of at unleash since I usually do unleash from range and I’d lose precious seconds here 😀
  • Line 6: in case I am not autoattacking, yet start autoattacking- for example stormstrike on cooldown when chaning targets
  • Line 7: in case we have a 1 handed weapon equipped stop the macro here, to avoid funny results with 2 weapons of the same name
  • Line 8: equip item:71782 in mainhand, Shatterskull Bonecrusher with Landslide
  • Line 9: equip item:71312 in off-hand, Gatecrasher with Landslide

Unleash Macro

#showtooltip
/castsequence [mod:shift] Flame Shock;[mod:alt]Frost Shock;[spec:1] reset=7 Unleash Elements,Flame Shock;[spec:2] reset=5 Unleash Elements,Greater Healing Wave
/startattack
/petattack

  • Line 1: show the proper tooltip for the active ability
  • Line 2:
  • while holding shift, cast flame shock
  • while holding alt, cast frost shock
  • cast unleash elements and on second click flame shock, in case you wont cast flame shock within 7 seconds it will reset to unleash – this will ensure that no matter what you always have flame shock after unleash flame
  • in spec 2, my pvp spec, it will cast greater healing wave after unleash, to get the bonus healing from unleash earthliving
  • Line 3: should you not already be autoattacking, it will start now
  • Line 4: if wolves are active, attack the current target (probably obsolete with the latest changes to pets)

Lightning Bolt Macro

#showtooltip
/castsequence [btn:2][mod:shift] reset=8target Lava Burst,Lightning Bolt,Lightning Bolt
/cast Lightning Bolt

  • Line 1: show the proper tooltip for the active ability
  • Line 2: in case you hold shift or rightclick the macro cast Lava burst, Lightning Bolt, Lightning Bolt
  • Line 3: just spam Lightning Bolt

Ghostwolf Macro, and Mounts

#show Ghost Wolf
/use [noform,nomounted,nobtn:2]Ghost Wolf
/cancelform [form]
/dismount [mounted]
/use [mod:ctrl]Mekgineer’s Chopper;[mod:alt]Traveler’s Tundra Mammoth;[flyable][mod:shift]Mimiron’s Head;Swift Spectral Tiger

  • Line 1: always display the tooltip for Ghost Wolf
  • Line 2: in case we are not in Ghost Wolf already, aren’t mounted and are not pressing button 2 (right-click) cast Ghost Wolf
  • Line 3: in case we are in Ghost Wolf, cancel it
  • Line 4: in case we are mounted, dismount
  • Line 5: only when right-clicking you come this far
  • control: use Chopper
  • alt: Tundra mammoth
  • flyable or shift: Mimirons Head
  • if all of the above fails it must be a ground mount area and it will use spectral Tiger
  • of course you need to have these mounts, change them as you please, mark their name in the macro editor and shift click on the mounts in your mount tab

Wind Shear Macro

#showtooltip
/clearfocus [@focus, dead]
/stopcasting
/cast [@focus, exists, nodead][] Wind Shear

  • Line 1: show the proper tooltip for the active ability
  • Line 2: clear focus if focus target is dead
  • Line 3: stopcasting
  • Line 4: if focus target exist windshear that otherwise the current target

 Shamanistic Rage Macro

#showtooltip Shamanistic Rage
/cast Shamanistic Rage
/dbm timer 00:15 Shamanistic Rage End!
/dbm timer 00:59 Shamanistic Rage CD

  • You do not really need this macro, but it gives a nice timer with deadly boss mods
  • Line 1: show the proper tooltip for the active ability
  • Line 2: cast Shamanistic Rage
  • Line 3: create a dbm timer for the duration of Shamanistic Rage
  • Line 4: create a dbm timer for the cooldown of Shamanistic Rage

Feral Spirit Macro

#showtooltip
/cast [nopet] Feral Spirit; [pet] Spirit Walk
/use 14
/dbm timer 00:29 Feral-Spirit End!
/dbm timer 01:59 Feral-Spirit CD

  • You do not really need this macro, but it gives a nice timer with deadly boss mods
  • Line 1: show the proper tooltip for the active ability
  • Line 2: in case no pets are active, cast feral spirit; with pet active cast Spirit Walk
  • Line 3: use trinket
  • Line 4: create a dbm timer for the duration of Feral Spirit
  • Line 5: create a dbm timer for the cooldown of Feral Spirit

Fire Nova, Magma Totem

#showtooltip
/cast [btn:2][mod:shift] Magma Totem; Fire Nova

  • Magma Totem
  • Line 1: show the proper tooltip for the active ability
  • Line 2: if you right-click or use shift cast Magma Totem; else cast Fire Nova

Windfury, Flame Tongue, Frostbrand, Earthliving Macro

#showtooltip
/cast [mod:shift][btn:2]Flametongue Weapon;[mod:alt]Frostbrand Weapon;[mod:ctrl]Earthliving Weapon;Windfury Weapon

  • To imbue your weapons as enhancement shaman, remove the existing ones and then left- and right-click the macro
  • Line 1: show the proper tooltip for the active ability
  • Line 2: if you right-click or use shift cast Flametongue Weapon, on alt Frostbrand Weapon, on control Earthliving Weapon and with no modifier you cast Windfury Weapon

Ancestral Spirit Macro

#showtooltip
/cast [mod:shift][btn:2] Mass Resurrection;[mod:alt]Have Group, Will Travel
/cast [help,dead][@none] Ancestral Spirit
/stopmacro [nohelp][nodead][nogroup]
/run SendChatMessage(„Resurrecting „..UnitName(„target“),“SAY“)

  • My Utility Macro
  • Line 1: show the proper tooltip for the active ability
  • Line 2: if you right-click or use shift cast Mass Ressurection; on alt summon party
  • Line 3: cast Ancestral Spirit if the target is friendly or dead or if we dont have a target (to ress released players)
  • Line 4: if the target is not friendly, or dead or we aren’t grouped, then stop here
  • Line 5: Say who you are ressing

Other Scripts

Show Feral Spirit Stats

#showtooltip Feral Spirit
/run if not oldHasPetUI then oldHasPetUI = HasPetUI; HasPetUI = function() return true, false; end end PetTab_Update() ToggleCharacter(„PetPaperDollFrame“)

  • create a tab in the character menu for feral spirit as seen here

Report Everyone AFK in a Battleground

/run for i=1,GetNumRaidMembers()-1 do local unit = „raid“..i local name,realm = UnitName(unit) if(realm) then ReportPlayerIsPVPAFK(name..“-„..realm) else ReportPlayerIsPVPAFK(name) end end

  • in case you are too busy to follow the activity in a bg, click this macro now and then, active players won’t be harmed, which afk bots will get marked afk

Eat Food

#showtooltip
/use [mod:shift] Skewered Eel;Conjured Mana Cake

  • pretty obvious, eat mage food or eel when you hold shift

Weapon ItemID’S

/run local function id(s) return strmatch(GetInventoryItemLink(„player“,s) or „“,“(item:%d+:%d+):“) end for i=16,17 do if id(i) then ChatFrame1:AddMessage(„/equipslot „..i..“ „..id(i)) end end

  • this macro will return the itemids for the equipped weapons

Note: You should check this link for other posts related to macros, it will show the most recent articles first.

6 Antworten auf „Enhancement Shaman Macros“

    1. None that would not fail in some situations. I am all for macros to make stupid stuff easier, but always end up in situations where these fail. The best solution I have come up with are the macros here and watch one of my recent videos to put up the keys like I do. then you just press the one that is off cooldown and the furthest left.
      I am talking about situations where you want to for example delay lava lash to properly spread lava lash, etc …

Schreibe einen Kommentar zu dootdk Antworten abbrechen

Deine E-Mail-Adresse wird nicht veröffentlicht.